#DEFINITIONS:  -*-sh-*-

# ARTS setup file for AMSUB simulations

Arts2 {


# 1. General
#-----------

output_file_formatSetZippedAscii

# AMSU uses Planck brightness temperatures
# ---
StringSet( y_unit, "PlanckBT" )

#
# modifiy the maximum propagation step, from the default(10.e3)
# to 250 m :
#
NumericSet( ppath_lmax, 250 )

# Surface
AgendaSet( surface_prop_agenda ){
  Ignore(rte_pos)
  Ignore(rte_gp_p)
  InterpSurfaceFieldToRteGps( surface_skin_t, atmosphere_dim,
                              rte_gp_lat, rte_gp_lon, t_surface )
  surfaceFlatReflectivity( surface_los, surface_rmatrix, surface_emission, 
                           f_grid, stokes_dim, atmosphere_dim, rte_los, 
                           surface_skin_t, surface_scalar_reflectivity )
} 

# 2. Spectroscopy
#----------------

# We take a smaller cutoff, since the line-by-line calculation is 
# only for O3, where only the local lines matter.
# Could be speed-optimized further by selecting only the relevant 
# lines from the line list.
ArrayOfLineshapeSpecCreate( abs_lineshapeDefine )
abs_lineshapeDefine( abs_lineshapeDefine, "Voigt_Kuntz6", "VVH", 5e9 )

SpeciesSet( abs_species, [ "H2O-PWR98",
                           "O3",
                           "O2-PWR93",
                           "N2-SelfContStandardType" ] )

# Read HITRAN catalog (needed for O3):
#abs_linesReadFromHitran2004( abs_lines,
#                             "/storage1/pool/lookup2/hitran2004/HITRAN04.par",
#                             80e9,
#                             200e9 )
#WriteXML( "ascii", abs_lines, "amsu/amsub.hitran04_lines.xml" )

ReadXML( abs_lines, "amsu/amsub.hitran04_lines.xml" )
abs_lines_per_speciesCreateFromLines

# WARNING: If you redefine abs_species, and want to do a line-by-line
# calculation, you also have to call
# abs_lines_per_speciesCreateFromLines again.


# 3. Sensor:
#-----------

# Definition of sensor position and LOS
# ---
ReadXML( sensor_los, "amsu/amsub.sensor_los.xml" )
nrowsGet( nrows, sensor_los )
ncolsGet( ncols, sensor_los )
MatrixSetConstant( sensor_pos, nrows, ncols, 850e3 )


# Sensor response setup
# ---

MatrixSet( sensor_description_amsu,
           [  89.00e9, 0.90e9, 1000e6 ;
      	     150.00e9, 0.90e9, 1000e6 ;
      	     183.31e9, 1.00e9,  500e6 ;
      	     183.31e9, 3.00e9, 1000e6 ;
      	     183.31e9, 7.00e9, 2000e6 ] )

sensor_responseSimpleAMSU

}